NETSHコマンドで取得したIPアドレスを変数に入れて判別するバッチファイルを作る方法

Wed, 08 Aug 2018 23:55:23 +0900

NETSHコマンドで表示されるIPアドレスの情報を変数に入れて命令を分岐させるバッチファイルのメモ。

現在のIPアドレスを取得して命令を分けたい

バッチファイルでPCをメンテナンスする際、メンテナンスするPCが属しているネットワークの系統別に命令を分岐したいなと思うことがあったのでチャレンジしてみました。それには現在のIPアドレスがどうなっているのか調べ、その値を変数に入れ、IF文で分岐する必要があります。

まずはNETSHコマンドで表示される値を確認

コマンドプロンプトで以下のコマンドと打って Enter を押すと現在のIPアドレスが表示されます。ここで表示されるIPアドレスを変数に入れたいと思います。

Windows 10 の場合

netsh interface ipv4 show address "イーサネット"

Windows 7 の場合

Windows 7 の場合は “イーサネット” の部分を “ローカルエリア接続” に変更しないと表示されません。

netsh interface ipv4 show address "ローカル エリア接続"

それでもうまく表示されない場合は “ローカルエリア接続” の部分を削除して実行して接続名を確認し、表示された接続名に書き直して再度実行してみてください。

netsh interface ipv4 show address

“IP アドレス” の部分だけ表示したいとき

netsh interface ipv4 show address "イーサネット" | find "IP アドレス"

Windows 7 の場合は “イーサネット” の部分を “ローカルエリア接続” に変更しないと表示されません。

IPアドレスを変数に入れて命令を分岐するバッチファイル例

もし、取得したIPアドレスが「192.168.」から始まるアドレスかどうかで命令を分岐するバッチファイルの例です。

Windows 10 や Windows 7 で異なるインターフェースの構成が “イーサネット” か “ローカルエリア接続” のどちらになっているかも判別するのも加えているので、どちらのOSでも使えるバッチファイルになっています。

@echo off

rem #遅延環境変数
setlocal enabledelayedexpansion

rem #インターフェースの構成が"イーサネット"か調べる
for /f "tokens=1,2* usebackq delims=^:" %%i in (`netsh interface ipv4 show address ^| findstr "イーサネット"`) do @set INTERFACE="イーサネット"

rem #インターフェースの構成が"ローカル エリア接続"か調べる
for /f "tokens=1,2* usebackq delims=^:" %%i in (`netsh interface ipv4 show address ^| findstr "ローカル エリア接続"`) do @set INTERFACE="ローカル エリア接続"

if !INTERFACE! == "イーサネット" (
	goto SearchIP
) else if !INTERFACE! == "ローカル エリア接続" (
	goto SearchIP
)
goto Unknown

:SearchIP
rem #IPアドレスを調べる
for /f "tokens=1,2* usebackq delims=^:" %%i in (`netsh interface ipv4 show address !INTERFACE! ^| findstr "IP アドレス" ^| findstr /n /r "."`) do @set IP=%%k

rem #取得したIPアドレス前後のスペースを削除
call :Trim %IP%

rem #192.168.から始まるIPアドレスか判別
echo.
echo %IP% | findstr /B 192.168. > nul
if %ERRORLEVEL% equ 0 (
	echo IPアドレスは%IP%です。
) else (
	echo 192.168.から始まるIPアドレスではありません。
)
echo.
goto End

:Unknown
echo.
echo インターフェースの構成名が不明です。
echo.

:End
endlocal
pause
exit

:Trim
set IP=%*

実行してみた結果

ちゃんとIF文で分岐した命令の通り、変数に格納されたIPアドレスが表示できました。

Windows 10 の場合

Windows 7 の場合

IPCONFIGコマンドを使った参考ページ

以下のページではIPCONFIGコマンドで取得したIPアドレスを変数に入れる方法を掲載しています。

IPCONFIGで取得したIPアドレスを変数に入れて判別するバッチファイルを作る方法

IPCONFIGで取得したIPアドレスを変数に入れて判別するバッチファイルを作る方法

Tue, 07 Aug 2018 21:33:24 +0900

コマンドプロンプトでIPCONFIGを実行して表示されるIPアドレスの情報を変数に入れるバッチファイルのメモ。

ネットワークの系統別に命令を分けたい

ネットワークの系統別に別けて命令を実行するバッチファイルが必要になったのでチャレンジしてみました。

まずはIPCONFIGで表示される値を確認

コマンドプロンプトで ipconfig と打って Enter を押すと以下の結果が表示されます。IPCONFIGは現在使用中のIPアドレスを表示するコマンドですが、この11行目に表示されているIPアドレスを変数に入れ、IF文で命令を分岐させたいのです。画面は Windows 10 で実行したときの画面です。

バッチファイル

以下のソースで IPCONFIG で表示される「IPv4アドレス」の欄にある値を変数に入れて処理することができました。Windows 10では11行目で表示されましたが、Windows 7では行数が異なったので、OSや環境によって取得したい値の行が何行目にあるのか注意が必要です。

@echo off
 
for /f "tokens=1,2* usebackq delims=^:" %%i in (`ipconfig ^| findstr /n /r "." ^| findstr /r "^11:"`) DO @set IP=%%k

rem 取得したIPアドレス前後のスペースを削除
call :Trim %IP%

rem 192.168.から始まるIPアドレスか判別
echo.
echo %IP% | findstr /B 192.168. > nul
if %ERRORLEVEL% equ 0 (
	echo IPアドレスは%IP%です。
) else (
	echo 192.168.から始まるIPアドレスではありません。
)
echo.
 
pause
 
:Trim
set IP=%*

実行してみた結果

ちゃんとIF文で分岐でき、変数に格納されたIPアドレスが表示できました。

以下のような取得方法も

取得したいIPアドレスの値がどの行にあるかOSによって異なるので、タイトルを指定して取得したい場合は以下の書き方でも取得できます。

for /f "tokens=1,2* usebackq delims=^:" %%i in (`ipconfig ^| findstr /n /r "." ^| findstr /r "IPv4 アドレス"`) DO @set IP=%%k

ただし、有線LANや無線LANとか仮想LANとかネットワークアダプタが複数あるPCの場合、一番最後のNICのアドレスを取得してしまいます。最初のNICのアドレスを指定して取得できる方法があるとは思いますが、また別の機会にチャレンジしてみたいと思います。

NETSHコマンドを使った参考ページ

以下のページではNETSHコマンドで取得したIPアドレスを変数に入れる方法を掲載しています。